PRO plt2hd,infile,charsize=charsize
; Plot the quadrature-detected RAFOS signal for a 2-hour file.
; Read in a 2-hour file of quadrature cross-correlation output:
;	r0124506.27d
; RWB, January 7, 2002.
  !p.background='ffffff'x; white
  !p.color=0; black
  str1=''; buffer
  day0=double(0); starting day for file (double-precision floating)
  lblk = long(0); length of averaging block used in downsampling
  npt = long(0); number of points in data arrays
  IF n_params() eq 0 THEN BEGIN; if no file on command line, get one
    infile='/usr/data/bland/pioneer/2001/r0124506.27d'; name of a PSM 2-hr data
			; file (beam-formed, mixed, downsampled, quad. ccor.)
    ;***** Ask for file name *****
     read,'input file: '+strmid(infile,strlen(infile)-12,12)+' : ',str1
     IF strlen(str1) gt 0 THEN strput,infile,str1,strlen(infile)-12
  ENDIF
;***** If the keyword charsize is passed, use it; otherwise use 1.0.
  IF n_elements(charsize) eq 0 THEN charsize=1.0
  !p.charsize=charsize;

  print,'infile:   ',infile
  openr, lun1, infile, /get_lun
  readu, lun1, day0; time of first point
  print,'day0 = ',day0
  readu, lun1, lblk; number of 1000-Hz points per averaged point
  print,'lblk = ',lblk
  readu, lun1, npt; number of points
  print,'npt = ',npt
  dt = double(.001)*lblk; time per point
  rsig = fltarr(npt); signal array
  tsig = findgen(npt)*dt; time array (sec)
  readu, lun1, rsig
  close,lun1
  free_lun,lun1
  plot,tsig,rsig, $
    title=strmid(infile,strlen(infile)-12,12), $
    xtitle='time (sec)', $
    ytitle='quadrature cross-correlation output'
END